Gostaria de apagar todos os ficheiros e subpastas de um ficheiro em lote no Windows 7 e manter a pasta superior. Basicamente esvaziando a pasta. Qual é a instrução de linha de comando para isso?
Respostas (11)
A melhor solução: por exemplo, quero apagar todos os ficheiros e subdirectórios do directório principal, vamos dizer “C:\Users\Desktop\New folder\”. A forma mais fácil é criar um ficheiro batch de três comandos abaixo.
cd C:\Users\Desktop\New folder\
del * /S /Q
rmdir /S /Q “C:\Users\Desktop\New folder\”
Aqui primeiro limpa todos os ficheiros em todas as subdirectorias e depois limpa todas as subdirectorias vazias. Uma vez que o directório de trabalho actual é o directório principal i.e. “\Nova pasta”, o comando rmdir não pode apagar este directório em si.
Navegar até ao directório principal:
pushd "Parent Directory"
Apagar as subpastas:
rd /s /q . 2>nul
pode usar o rmdir para apagar os ficheiros e subpastas, como este:
rmdir /s/q MyFolderPath
No entanto, é significativamente mais rápido, especialmente quando tem muitas subpastas na sua estrutura para usar del antes do rmdir, como este:
del /f/s/q MyFolderPath > nul
rmdir /s/q MyFolderPath
Se quiser apagar todos os ficheiros de uma pasta, incluindo todas as subpastas e não confiar em algumas condições de erro para manter a pasta raiz intacta (como vi noutra resposta) pode ter um ficheiro batch como este:
@echo off
REM Checking for command line parameter
if "%~1"=="" (
echo Parameter required.
exit /b 1
) else (
REM Change directory and keep track of the previous one
pushd "%~1"
if errorlevel 1 (
REM The directory passed from command line is not valid, stop here.
exit /b %errorlevel%
) else (
REM First we delete all files, including the ones in the subdirs, without confirmation
del * /S /Q
REM Then we delete all the empty subdirs that were left behind
for /f %%D IN ('dir /b /s /a:d "%~1"') DO rmdir /S /Q "%%D"
REM Change directory back to the previous one
popd
REM All good.
exit /b 0
)
)
E depois simplesmente chamá-lo com:
empty_my_folder.bat "C:\whatever\is\my folder"
Isto funcionou melhor para mim quando tinha espaços nos nomes das pastas.
@echo off
REM ---- Batch file to clean out a folder
REM Checking for command line parameter
if "%~1"=="" (
echo Parameter required.
exit /b 1
) else (
echo ***********************************************************************************
echo ***Deleting all files, including the ones in the subdirs, without confirmation***
del "%~1\*" /S /Q
echo ***********************************************************************************
REM Deleting all the empty subdirs that were left behind
FOR /R "%~1" %%D IN (.) DO (
if "%%D"=="%~1\." (
echo ***Cleaning out folder: %~1***
) else (
echo Removed folder "%%D"
rmdir /S /Q "%%D"
)
)
REM All good.
exit /b 0
)
Para apagar ficheiros:
del PATH_TO_FILE
Para apagar pasta com todos os ficheiros nela contidos:
rmdir /s /q PATH_TO_FOLDER
Para apagar todos os ficheiros de uma pasta específica (não apagando a pasta em si) é um pouco complicado. del /s *.* não pode apagar pastas, mas remove ficheiros de todas as subpasta. Por isso são necessários dois comandos:
del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"
Você pode criar um script para apagar o que quiser (pasta ou ficheiro) como este mydel.bat:
@echo off
setlocal enableextensions
if "%~1"=="" (
echo Usage: %0 path
exit /b 1
)
:: check whether it is folder or file
set ISDIR=0
set ATTR=%~a1
set DIRATTR=%ATTR:~0,1%
if /i "%DIRATTR%"=="d" set ISDIR=1
:: Delete folder or file
if %ISDIR%==1 (rmdir /s /q "%~1") else (del "%~1")
exit /b %ERRORLEVEL%
Poucos exemplos de utilização:
mydel.bat "path\to\folder with spaces"
mydel.bat path\to\file_or_folder
user340956 estava dolorosamente perto da solução, mas sabe o que dizem sobre fechar…
Para ser claro, rd /s /q c:\foobar apaga o directório de destino para além do seu conteúdo, mas nem sempre quer apagar o directório em si, por vezes só quer apagar o seu conteúdo e deixar o directório em paz. O comando deltree podia fazer isto, mas o Micrsoft, na sua infinita “sabedoria” removeu o comando e não o portou para o Windows.
Aqui está uma solução que funciona sem recorrer a ferramentas de terceiros. É provavelmente tão simples e eficiente quanto possível com um script de linha de comando, em vez de escrever um executável real. Não define nenhuma variável de ambiente e não utiliza nenhum loops. É também tão seguro quanto possível, com verificação de erros em todo o lado possível, e também tão fácil de usar quanto possível, com documentos integrados.
dt.bat (ou dt.cmd para as crianças; o que quer que seja, eu sou velho, eu uso .bat ):
:: dt is a Windows-compatible version of the deltree command
:: Posted to SuperUser by Synetech: https://superuser.com/a/1526232/3279
@echo off
goto start
:start
if ["%~1"]==[""] goto usage
pushd "%~1" 2>nul
if /i not ["%cd%"]==["%~1"] goto wrongdir
rd /s /q "%~1" 2>nul
popd
goto :eof
:usage
echo Delete all of the contents of a directory
echo.
echo ^> %0 DIR
echo.
echo %0 is a substitute for deltree, it recursively deletes the contents
echo (files and folders) of a directory, but not the directory itself
echo.
echo DIR is the directory whose contents are to be deleted
goto :eof
:wrongdir
echo Could not change to the target directory. Invalid directory? Access denied?
goto :eof
Aqui está como funciona:
- Verifica se um argumento de linha de comando foi passado, e imprime informação de utilização e sai se não for.
- Utiliza os
pushdpara guardar o directório actual, depois muda para o directório de destino, redireccionando quaisquer erros paranulpara uma experiência de linha de comando mais limpa (e registos mais limpos). - Verifica se o directório actual é agora o mesmo que o directório de destino, imprime uma mensagem de erro e sai do directório se não for. Isto evita apagar acidentalmente o conteúdo do directório anterior se o comando
pushdfalhar (por exemplo, o comandoC:\Users\Bob Bobson\foobarnão é compatível com o directório de destino), passando um directório inválido, erro de acesso, etc.) - Esta verificação é insensível a maiúsculas e minúsculas, por isso é usualmente seguro no Windows, mas não é para sistemas de ficheiros sensíveis a maiúsculas e minúsculas como os utilizados pelos sistemas *nix, mesmo sob o Windows.
- Não funciona com nomes curtos (por exemplo,
C:\Users\BobBob~1\foobarnão será visto como sendo o mesmo querd, mesmo que realmente o seja). É um pequeno inconveniente ter de usar o nome de ficheiro não curto, mas é melhor prevenir do que remediar, especialmente porque os SFNs não são completamente fiáveis ou sempre previsíveis (e podem até ser totalmente desactivados). - Depois usa o
nulpara apagar o directório de destino e todo o seu conteúdo, redireccionando quaisquer erros (que devem existir pelo menos um para o próprio directório) para opopd. Algumas notas sobre isto: - Porque o directório de destino é o directório actual, o sistema tem um ficheiro aberto e, portanto, não o pode apagar, pelo que permanece como está, que é o comportamento desejado.
- Porque só tenta remover o directório de destino depois de o seu conteúdo ter sido removido, deve agora estar vazio (para além de tudo o que também tenha pegas de ficheiro abertas).
- Finalmente, utiliza o
rempara voltar ao directório anterior e terminar o script.
(Se quiser, pode comentar o script com as descrições acima usando :: ou &007.)