Exportar uma folha de cálculo Excel para um ficheiro de texto de largura fixa?

Penso que o mais próximo que se pode obter da funcionalidade nativa do Excel é Save As | Formatted Text (Space Delimited) (*.prn). Determinará automaticamente as larguras e introduzirá espaços para almofadar a essa largura, conforme necessário.

Além disso, é necessário ter uma macro ou outro suplemento que lhe permita fazer mais.

Se tiver o Office Professional, pode abrir o seu ficheiro Excel no Access, e depois Exportar do Access. O Access permitir-lhe-á especificar um esquema de largura fixa para o seu ficheiro exportado, e dá-lhe controlos extremamente granulares para especificar essas larguras.

Uau, eu próprio ia fazer esta pergunta, mas já a tinha feito. Toda a saída da prancheta Excel é delimitada por defeito por uma aba. Isto é um pouco irritante para a saída de texto simples “real” quando se tem uma fonte de largura fixa mas não necessariamente suporte de separador delimitador.

De qualquer modo, encontrei e modifiquei uma pequena Macro Excel que irá copiar a região actualmente seleccionada como uma simples tabela ASCII de largura fixa - como tal:

187712 201 37 0.18 2525 580 149 0.25 136829 137 43 0.31

Aqui está o código da Macro. Para o utilizar, certifique-se de activar o separador Desenvolvedor em Opções Excel se estiver a utilizar o Excel 2007 ou posterior.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)

    Dim temp As Integer
    Dim cellsize As Integer
    cellsize = 0
    For c = 1 To selectedcols
        temp = Len(CStr(Cells(1, c)))
        If temp > cellsize Then
            cellsize = temp
        End If
    Next c
    cellsize = cellsize + 1

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(selectedcols * cellsize)
        For c = 1 To selectedcols
            Mid(line, c * cellsize - cellsize + 1, cellsize) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Primeiro, formate os seus dados como Courier New (ou alguma outra fonte de largura fixa). Depois, salve como .prn e obterá uma verdadeira largura fixa.

Expandindo a resposta de Jeff Atwood, uma vez que não me deixaria comentá-la:

Eu modifiquei a sua macro para definir a largura da coluna para a célula mais larga daquela coluna e para ter cada coluna a sua própria largura. A sua macro só encontrou a célula mais larga na primeira linha e depois definiu a largura de todas as colunas para ela.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long, linesize As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)
    ReDim CellSizes(1 To selectedcols, 2) As Integer

    Dim temp As Integer
    Dim cellsize As Integer
    linesize = 0
    For c = 1 To selectedcols
        cellsize = 0
        For r = 1 To selectedrows
            temp = Len(CStr(Cells(r, c)))
            If temp > cellsize Then
                cellsize = temp
            End If
        Next
        CellSizes(c, 0) = cellsize + 1
        CellSizes(c, 1) = linesize
        linesize = linesize + cellsize + 1
    Next c

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(linesize)
        For c = 1 To selectedcols
            Mid(line, CellSizes(c, 1) + 1, CellSizes(c, 0)) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Isto é um assassino para mim. Tem também algumas opções. http://www.sensefulsolutions.com/2010/10/format-text-as-table.html

Funciona com o Access out of the box: https://support.office.com/en-ie/article/export-data-to-a-text-file-f72dfc38-a8a0-4c5b-8c2c-bf2950814140#bmsteps com esta forma geri-o bastante fácil e rápido - melhor do que com o Excel. No meu caso, foi uma conversão da tabela.