Depois de uma nova instalação do Windows - XP ou 7 - como posso “forçar” as actualizações do Windows?
Não quero ter “velhas” actualizações do Windows após uma semana, por isso poderia ser feito “num só passo”? Existem alguns comandos “mágicos” que forçam o Windows a verificar as actualizações, e se existirem, instalá-las?
Para além da forma habitual de utilizar o Windows Update, pode forçar uma verificação a partir de uma linha de comando.
Abra uma linha de comando de administrador e execute:
C:\> %windir%\system32\wuauclt.exe /detectnow
Wuauclt.exe é o Cliente AutoUpdate do Windows Update e é utilizado para verificar as actualizações disponíveis (para as várias versões da plataforma MS Windows) a partir do Microsoft Update.
Isto não vai forçar uma instalação.
Pode verificar e instalar actualizações automaticamente utilizando um script. Isto funcionará tanto no XP como no Windows 7.
Há uma série de scripts disponíveis para download, aqui é meu :
' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()
Do
WScript.Echo
WScript.Echo "Searching for approved updates ..."
WScript.Echo
Set updateSearch = updateSearcher.Search("IsInstalled=0")
If updateSearch.ResultCode <> 2 Then
WScript.Echo "Search failed with result code", updateSearch.ResultCode
WScript.Quit 1
End If
If updateSearch.Updates.Count = 0 Then
WScript.Echo "There are no updates to install."
WScript.Quit 2
End If
Set updateList = updateSearch.Updates
For I = 0 to updateSearch.Updates.Count - 1
Set update = updateList.Item(I)
WScript.Echo "Update found:", update.Title
Next
WScript.Echo
updateDownloader.Updates = updateList
updateDownloader.Priority = 3
Set downloadResult = updateDownloader.Download()
If downloadResult.ResultCode <> 2 Then
WScript.Echo "Download failed with result code", downloadResult.ResultCode
WScript.Echo
WScript.Quit 1
End If
WScript.Echo "Download complete. Installing updates ..."
WScript.Echo
updateInstaller.Updates = updateList
Set installationResult = updateInstaller.Install()
If installationResult.ResultCode <> 2 Then
WScript.Echo "Installation failed with result code", installationResult.ResultCode
For I = 0 to updateList.Count - 1
Set updateInstallationResult = installationResult.GetUpdateResult(I)
WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode
Next
WScript.Quit 1
End If
If installationResult.RebootRequired Then
WScript.Echo "The system must be rebooted to complete installation."
WScript.Quit 3
End If
WScript.Echo "Installation complete."
Loop
Executa isto a partir da linha de comando desta forma:
cscript wsusupdate.vbs
O meu guião é apenas minimamente funcional mas pode ainda ser útil. Existem outros scripts deste tipo disponíveis com muitas características adicionais, tente uma pesquisa no Google.
Outra forma de forçar uma verdadeira nova procura de actualizações é limpar a ardósia, apagando todas as actualizações armazenadas em *%windir%\Windows\SoftwareDistribution\Download\Download* :
NET STOP wuauserv
RD /S /Q %windir%\SoftwareDistribution\Download
NET START wuauserv
Depois vá para Windows Update, e “Check for updates”. Pode demorar uma hora, porque cada ficheiro actualizável no volume do seu sistema é verificado (as subsequentes “Verificações de actualizações” serão rápidas). Esta abordagem elimina erros, actualizações em erro, e produz um sistema limpo e actualizado, pelo menos na medida em que a MS o veja.
estou a utilizar uma segunda ferramenta chamada wuinstall para actualizar a instalação de janelas novas. com isso é possível automatizar todo o processo de actualização, incluindo reinicializações automáticas. penso que é uma das formas mais rápidas de actualizar uma janela nova sem a presença do utilizador.
Descobri que se, como parte da sua nova instalação no Windows 7, actualizou o IE ou ainda não executou o IE e respondeu às perguntas introdutórias, que o Windows Update irá dar-lhe um erro. Também não encontrei uma forma de mudar o Windows Update para o Microsoft Update sem passar pelo GUI, por isso inicio manualmente o IE, inicializo-o e depois configuro o Windows Update através do GUI, para que possa mudar para o Microsoft Update e evitar o erro inicial. A sua quilometragem pode variar.