No Windows 7, como alterar as definições proxy da linha de comandos?

Solução simples e funcional recuperada de http://www.ehow.com/how_6887864_do-proxy-settings-command-prompt_.html

Comando para permitir a utilização de proxy:

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" ^
    /v ProxyEnable /t REG_DWORD /d 1 /f

Comando para desactivar a utilização de proxy:

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" ^
    /v ProxyEnable /t REG_DWORD /d 0 /f

Comando para alterar o endereço proxy:

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" ^
    /v ProxyServer /t REG_SZ /d proxyserveraddress:proxyport /f

Adicionei a continuação da linha (^) para melhorar a legibilidade. Também, neste caso, é mais uma configuração por utilizador do que uma configuração a nível do sistema.

NetSh winhttp set proxy devem ser úteis. Aqui estão os comandos:

netsh winhttp set proxy myproxy

netsh winhttp set proxy myproxy:80 "<local>bar"

netsh winhttp set proxy proxy-server="http=myproxy;https=sproxy:88" bypass-list="*.contoso.com"

Fi-lo em C#, mas a filosofia é a mesma, escrevendo para o registo, pelo que as instruções seguintes podem ser extrapoladas para o comando de linha. Devem ser feitas três coisas:

1. Escrever no Registo “HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings”, em ProxyEnable: 1 para activar, 0 para desactivar

2. Escreva no Registo “HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings”, em ProxyServer: xxx.xxx.xxx.xxx.xxxx:yyyyy (xxx… é o IP, yy… é a porta)

3. Depois de executar os passos 1 e 2 terá escrito para registar a activação do proxy e o IP e a porta, mas se abrir o browser irá notar que não é suficiente, ainda não pode navegar. O terceiro passo consiste em alterar o registo relativamente às definições de ligações:

“Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections” em “DefaultConnectionSettings”.

Repare que embora (pelo menos para W7) existam 204 bytes neste registo, apenas tem de modificar o byte 8 (9º, uma vez que o byte 0 é o primeiro). O valor do byte 8 não só contém informação sobre a activação/desactivação do proxy, mas também sobre outras funcionalidades:

//09 when only 'Automatically detect settings' is enabled 
        //03 when only 'Use a proxy server for your LAN' is enabled
        //0B when both are enabled
        //05 when only 'Use automatic configuration script' is enabled
        //0D when 'Automatically detect settings' and 'Use automatic configuration script' are enabled
        //07 when 'Use a proxy server for your LAN' and 'Use automatic configuration script' are enabled
        //0F when all the three are enabled. 
        //01 when none of them are enabled.

No meu caso, a ‘Detecção automática de definições’ está sempre activada, pelo que mudo o valor do byte 8 de 09 para 0B e viceversa para activar e desactivar o proxy.

Criar um ficheiro de lote e colar de acordo com o conteúdo (irá alternar o estado Proxy),

@echo off

FOR /F "tokens=2* delims= " %%A IN ('REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable') DO SET currentProxy=%%B
rem ECHO currentProxy=%currentProxy%

if %currentProxy%==0x1 (
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f
echo Proxy Disabled
) else (
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f
echo Proxy Enabled
  )

pause

Espero estar a apontar na direcção correcta, mas se estiver a tentar aceder às definições de proxy através de “Opções de Internet”, basta abrir o menu inicial e digitar “opção Internet” (qualquer definição ou aplicação que possa localizar desta forma também o exemplo “proxy”). Deverá então reconhecer este menu e ser capaz de adicionar as suas definições necessárias.