2012-10-18 02:44:09 +0000 2012-10-18 02:44:09 +0000
32
32

Como obter o nome do ficheiro apenas sem caminho na linha de comando do windows? 

for /r %f in (*) do echo %f

Dá o nome do ficheiro de saída juntamente com todo o caminho 

\path\to\dir\<filename>

Como obter apenas o <filename> sem o caminho incluído? Preciso de usar essa cadeia de ‘nome de ficheiro’.

Também, é possível fazer o seguinte, uma vez adquirido o nome do ficheiro? 

for /r %%f in (*) do (
echo "blah blah blah 'filename'" >> blahblah_filename.txt
)
Fonte

Respostas (2)

57
57
57
2012-10-18 03:00:24 +0000

Usar %~nxf para <filename>.<extension>.

E sim, pode fazer: 

for /r %%f in (*) do (
echo "blah blah blah '%%~nxf'" >> blahblah_%%~nxf.txt
)

Ver for /?: 

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

    %~I - expands %I removing any surrounding quotes (")
    %~fI - expands %I to a fully qualified path name
    %~dI - expands %I to a drive letter only
    %~pI - expands %I to a path only
    %~nI - expands %I to a file name only
    %~xI - expands %I to a file extension only
    %~sI - expanded path contains short names only
    %~aI - expands %I to file attributes of file
    %~tI - expands %I to date/time of file
    %~zI - expands %I to size of file
    %~$PATH:I - searches the directories listed in the PATH
                   environment variable and expands %I to the
                   fully qualified name of the first one found.
                   If the environment variable name is not
                   defined or the file is not found by the
                   search, then this modifier expands to the
                   empty string

The modifiers can be combined to get compound results:

    %~dpI - expands %I to a drive letter and path only
    %~nxI - expands %I to a file name and extension only
    %~fsI - expands %I to a full path name with short names only
    %~dp$PATH:I - searches the directories listed in the PATH
                   environment variable for %I and expands to the
                   drive letter and path of the first one found.
    %~ftzaI - expands %I to a DIR like output line

In the above examples %I and PATH can be replaced by other valid
values. The %~ syntax is terminated by a valid FOR variable name.
Picking upper case variable names like %I makes it more readable and
avoids confusion with the modifiers, which are not case sensitive.
Fonte
0
0
0
2018-12-10 08:26:31 +0000

Ainda não posso comentar, mas creio que o seguinte deve ser notado para evitar confusões.

Embora f possa ser usado como nome de variável FOR, é melhor usar outra letra para evitar confundi-la com a letra de formato f (que, como indicado na resposta de Bob, devolve o nome completo do caminho), ou pelo menos usar um F maiúsculo.
Fonte