Na mesma linha de pensamento que Google Sheets pode não ser para todos, esta macro pode não ser para todos mas pode ser para alguém.
Percorre o intervalo seleccionado e substitui células transbordantes por texto truncado.
As bandeiras determinam se:
o texto ofensivo é copiado para o mesmo endereço relativo numa nova folha de trabalho ou se é descartado.
o texto truncado é codificado ou ligado através da fórmula da folha de trabalho =LEFT()
o texto truncado é hiperligado à cadeia completa da nova folha.
Por defeito é para reter dados e utilizar ambos os links.
Option Explicit
Sub LinkTruncatedCells()
Dim rng As Range: Set rng = Selection
Dim preserveValues As Boolean: preserveValues = True
Dim linkAsFormula As Boolean: linkAsFormula = True
Dim linkAsHyperlink As Boolean: linkAsHyperlink = True
Dim w As Single
Dim c As Range
Dim r As Range
Dim t As Long
Dim l As Long
Dim s As String
Dim ws As Worksheet
Dim ns As Worksheet
Application.ScreenUpdating = False
Set ws = rng.Parent
For Each c In rng.Columns
w = c.ColumnWidth
t = 0
l = 0
For Each r In c.Rows
If Len(r) > l Then
s = r
If CBool(l) Then r = Left(s, l)
Do
r.Columns.AutoFit
If r.ColumnWidth > w And Len(s) > t Then
t = t + 1
r = Left(s, Len(s) - t)
l = Len(r)
End If
Loop Until t = Len(s) Or r.ColumnWidth <= w
r.ColumnWidth = w
If r <> s And preserveValues Then
If ns Is Nothing Then
Set ns = ws.Parent.Worksheets.Add(after:=ws)
End If
ns.Range(r.Address) = s
If linkAsFormula Then r.Formula = "=LEFT(" & ns.Name & "!" & r.Address & "," & l & ")"
If linkAsHyperlink Then ws.Hyperlinks.Add Anchor:=r, Address:="", SubAddress:= _
ns.Range(r.Address).Address(external:=True)
End If
End If
Next r
Next c
ws.Activate
Application.ScreenUpdating = True
End Sub
Nota final: Utilizei-o para projectos pessoais e achei-o fiável, mas por favor save e faça cópias de segurança do seu trabalho antes de tentar qualquer macro* não familiar.
